; Restrict to lexical idiom NPs, as in "take care of ..."
;; DPF 2018-09-12 - Removed COMPS..MIN bare_nom_rel since |take care of NP|
;; needs bare-NP (ordinary `care', not an idiomatic one).
v_np-pp_e-idm_le := main_verb & 
  [ SYNSEM empty_prep_trans_verb & 
	   [ LOCAL.CAT [ VAL.COMPS < [ OPT -, 
			               LEX +,
				       LOCAL.CAT.HEAD noun ], 
				     [ OPT - ] > ],
             LKEYS [ --OCOMPKEY #ocmin,
                     --+OCOMPKEY #ocmin ] ],
    IDIOM + ].

;; Block reflexive pronouns (indeed, any) for second NP, to avoid silly parse
;; for "He cooked the dinner himself"
v_np-np_only_le := main_verb & 
  [ ALTS.DATIVE -,
    SYNSEM ditrans_only_verb & 
	   [ LOCAL.CAT [ VAL.COMPS < [ OPT -,
				       MODIFD.RPERIPH bool ], 
				     [ OPT -,
				       --MIN basic_nonpro_rel,
				       MODIFD.RPERIPH bool ] > ],
             LKEYS [ --OCOMPKEY #ocmin,
                     --+OCOMPKEY #ocmin ] ] ].

v_np-np_le := main_verb & 
  [ SYNSEM ditrans_verb &
	   [ LOCAL.CAT [ VAL.COMPS < [ OPT -,
	                               MODIFD.RPERIPH bool ], 
	                             [ OPT -,
				       --MIN basic_nonpro_rel,
	                               MODIFD.RPERIPH bool ] > ],
	     LKEYS [ --OCOMPKEY #ocmin,
		     --+OCOMPKEY #ocmin ] ] ].

;; Pronoun as second NP
v_np-nppro_le_rbst := main_verb & 
  [ ALTS.DATIVE -,
    SYNSEM ditrans_only_verb &
	   [ LOCAL.CAT [ VAL.COMPS < [ OPT -,
	                               MODIFD.RPERIPH bool,
				       NONLOC.SLASH 0-dlist ], 
	                             [ OPT -,
				       --MIN pron_rel,
	                               MODIFD.RPERIPH bool ] > ],
	     LKEYS [ --OCOMPKEY #ocmin,
		     --+OCOMPKEY #ocmin ] ],
   GENRE robust ].

;; DPF 2017-04-03 - Added COMPS..MOD..MODIFD.RPERIPH constraint to prevent 
;; robust analysis of |the milk went bad|.
;;
v_adv_le := norm_basic_main_verb &
  [ SYNSEM adv_verb & 
      [ LOCAL.CAT.VAL.COMPS.FIRST.LOCAL.CAT.HEAD.MOD.FIRST.MODIFD.RPERIPH + ],
    INFLECTD - ].

;; Prevent rare passives to avoid spurious analysis of e.g. 
;; |I arrived felt bored|
;; Also block extraction, as for spurious analysis of |he feels [embarrassed he
;; hasn't ever seen the movie]|
;;
v_np-prd_oeq_le := main_verb_mliszt & 
  [ SYNSEM obj_equi_non_trans_prd_verb &
           [ LOCAL.CAT.VAL.COMPS.REST.FIRST.NONLOC.SLASH 0-dlist ] ].

;; |they hope me to succeed|
v_np-vp_sor_le_rbst := main_verb_mliszt & 
  [ SYNSEM sor_verb,
    GENRE robust ].

;; |they elected him the president|
v_np-np_nbar_le_rbst := main_verb & 
  [ ALTS.DATIVE -,
    SYNSEM ditrans_only_verb & 
	   [ LOCAL.CAT [ VAL.COMPS < [ OPT - ], 
				     [ OPT -,
				       --MIN non_proper_rel ] > ],
             LKEYS [ --OCOMPKEY #ocmin,
                     --+OCOMPKEY #ocmin ] ],
    GENRE robust ].

; Restrict normal transitives missing object to --MAL3SG + to prevent
; these from appearing in conjoined verb phrases, avoiding spurious ambiguity
; for e.g. "Kim buys and sells books"
; DPF 19-feb-10 - Also constrain to SLASH 0-dlist, to avoid mis-analysis for
; e.g. `Mark brought the [cookies he made for] his class.'
; DPF 19-apr-10 - --COMPKEY is hack to prevent attrib-adj LR, as in 
; "Mariah is making pasta"
v_-_le_rbst := main_verb & 
  [ SYNSEM unerg_verb &
           [ LOCAL.CAT.HEAD [ --MAL3SG + ],
	     NONLOC.SLASH 0-dlist,
	     LKEYS.--COMPKEY selected_rel ],
    ALTS.NGER -,
    GENRE robust ].

;; |he had his health ruin| => ruined
v_-_le_pas_rbst := main_verb & 
  [ SYNSEM unerg_verb,
    GENRE robust ].

v_p_le_pas_rbst := main_verb & 
  [ SYNSEM particle_verb &
	   [ LKEYS [ --COMPKEY #cmin,
                     --+COMPKEY #cmin ] ],
    GENRE robust ].

; e.g. 'tell'
; Exclude robust 3sg in CP complement, to avoid competing treatment for e.g.
; `she told her brother borrow her book'.
v_cp_le_rbst := main_verb & 
  [ SYNSEM cp_intrans_verb &
           [ LOCAL.CAT [ VAL.COMPS < [ LOCAL.CAT.HEAD.--MAL3SG -,
				       NONLOC.SLASH 0-dlist ] > ] ],
    ALTS.CPFRAG -,
    GENRE robust ].

; |we inquired that he arrived|
v_cp_le_ques_rbst := main_verb & 
  [ SYNSEM cp_intrans_verb &
           [ LOCAL.CAT [ VAL.COMPS < [ LOCAL.CAT.HEAD.--MAL3SG -,
				       NONLOC.SLASH 0-dlist ] > ] ],
    ALTS.INVQ -,
    GENRE robust ].

; e.g. `know': |*we know where is the restaurant|
v_cp_fin-inf-q-mc_le_rbst := main_verb & 
  [ SYNSEM cp_ques_fin_inf_mc_verb,
    GENRE robust ].

; e.g. 'tell him borrow her book'
v_np-vp_bse_le_rbst := main_verb_mliszt & 
  [ SYNSEM obj_equi_bse_verb,
    GENRE robust ].

; e.g. `This lets the cat to enter'
;; DPF 2018-04-03 - To avoid overuse, constrain NP to exclude partitives
v_np-vp_oeq_le_rbst := main_verb & 
  [ SYNSEM obj_equi_verb &
           [ LOCAL.CAT.VAL.COMPS.FIRST.LOCAL.CAT.HEAD non_partn ],
    GENRE robust ].

; 'She enables to win.'
; Missing direct object
;
v_vp_seq_le_rbst := main_verb & 
  [ SYNSEM subj_equi_verb,
    GENRE robust ].

; |succeeded to arise| => succeeded in arising
;
v_vp_pp-in_le_rbst := main_verb & 
  [ SYNSEM subj_equi_verb,
    GENRE robust ].

; (ERB 2003-10-23) For subject equi verbs, with the infinitival
; marker "to" dropped

; 'She wants win.'
v_vp_seq-bse_le_rbst := main_verb_mliszt & 
  [ SYNSEM subj_equi_bse_verb,
    GENRE robust ].

;; Missing |to| for raising: |they tend win.|
v_vp_ssr-nimp_le_rbst := main_verb & 
  [ SYNSEM ssr_bse_noimp_verb,
    GENRE robust ].

;; |she enjoys to swim|
v_vp_seq-prp_le_rbst := main_verb & 
  [ SYNSEM subj_equi_verb,
    GENRE robust ].

; |don't forget taking your coat|
v_vp_ssr-prp_le_rbst := main_verb & 
  [ SYNSEM ssr_prp_verb,
    GENRE robust ].

;; |she explained to open the box| => how to open
v_vp_wh_le_rbst := main_verb & 
  [ SYNSEM subj_equi_verb,
    GENRE robust ].

; 'ask' - block dative shift
v_np-np*_nodat_le := main_verb & 
  [ SYNSEM ditrans_only_verb & 
	   [ LOCAL.CAT [ VAL.COMPS < [ OPT - ], [ OPT + ] > ] ] ].

; |explained the students the method|
; Block dative shift
v_np-np_le_rbst := main_verb & 
  [ SYNSEM ditrans_verb &
	   [ LOCAL.CAT [ VAL.COMPS < [ OPT -,
				       NONLOC.SLASH 0-dlist ],
				     [ OPT - ] > ],
	     LKEYS [ --OCOMPKEY #ocmin,
		     --+OCOMPKEY #ocmin ] ],
    ALTS.DATIVE -,
    GENRE robust ].

; `like' - block bare-sg objects:
; |I didn't like tadpole hunting|
;;
v_np-prd_oeq-ntr-x_le := main_verb_mliszt & 
  [ SYNSEM obj_equi_non_trans_prd_verb &
	   [ LOCAL.CAT.VAL.COMPS.FIRST.LOCAL.CAT.HEAD.--BARE -,
	     LKEYS [ --OCOMPKEY #ocmin,
		     --+OCOMPKEY #ocmin ] ] ].

;; For wrong prep marker as in |allocated it of Kim|
;; |mistake him as Kim|
v_np-pp_e_le_rbst := main_verb & 
  [ SYNSEM empty_prep_trans_verb &
	   [ LOCAL.CAT [ VAL.COMPS < [ OPT - ], [ OPT - ] > ],
             LKEYS [ --OCOMPKEY #ocmin,
                     --+OCOMPKEY #ocmin ] ],
    GENRE robust ].

; |cost money from me| => |cost me money|
v_np-pp_np_le_rbst := main_verb & 
  [ SYNSEM prep_trans_verb &
	   [ LOCAL.CAT [ VAL.COMPS < [ OPT - ], [ OPT - ] > ],
             LKEYS [ --OCOMPKEY #ocmin,
                     --+OCOMPKEY #ocmin ] ],
    GENRE robust ].

; For e.g. "went the store"
; Add NORM no_rel to block v_mod rule for e.g. "went to visit her house"
; and ngerund rule as in |sitting on the lawn waiting|.
; Block for |waited an hour|
;
v_np_pp_le_rbst := main_verb & 
  [ SYNSEM np_non_trans_verb &
     [ LOCAL.CAT [ HEAD.MINORS.NORM no_rel,
		   VAL.COMPS < canonical_synsem &
			       [ OPT -,
				 LOCAL.CAT.HEAD.--BARED -,
				 --SIND.SORT entity,
				 PUNCT.RPUNCT comma_or_clause_or_no_punct ] >]],
    GENRE robust ].

v_np_locinv-mv_le_rbst := basic_loc_inv_verb_word &
  [ INFLECTD -,
    SYNSEM loc_inv_mv_synsem &
           [ LOCAL.CAT.VAL.COMPS.FIRST.--MIN pron_rel ],
    GENRE robust ].

; Should be subjunctive CP: |we wish that he arrives|
v_cp_sbjnct_le_rbst := norm_basic_main_verb & 
  [ INFLECTD -,
    ALTS.CPFRAG -,
    SYNSEM pp_cp_fin_prop_verb &
    	   [ LOCAL.CAT.VAL.COMPS.REST.FIRST.LOCAL.CAT.HEAD
                                                    [ TAM [ TENSE nonpast,
							    MOOD indicative ],
						      --MODAL - ] ],
    GENRE robust ].

; |Kim made [it] easier to leave|
; Block use for |made sure to leave|
;; NORM norm_rel blocks J-V compounds like |proud-making| with these verbs
;;
v_prd_seq_le_rbst := main_verb_mliszt & 
  [ SYNSEM subj_equi_prd_v_a_verb &
	   [ LOCAL.CAT [ VAL.COMPS.FIRST.LOCAL.CAT.HEAD.--IDIOMPART -,
	                 HEAD.MINORS.NORM norm_rel ] ],
    GENRE robust ].

modal_pos_lex_ent :+
  [ SYNSEM.LOCAL.CAT.HEAD.--MODAL + ].

; For |take place the event|
v_nb-np_le_mal := main_verb_mliszt & 
  [ SYNSEM basic_ditrans_nbar_np_verb &
    	   [ LOCAL.CAT.VAL.COMPS.FIRST.LOCAL.CAT.VAL.SPR.FIRST.OPT - ],
    ALTS.PASSIVE - ].

v_cp_q_le := main_verb & 
  [ SYNSEM cp_ques_intrans_verb ].