root-sent := sign &
[ SYNSEM synsem-match &
         [ LOCAL.CAT [ HEAD  head-super-verb & [ FORM-VERB form-verb-fin ],
                       VAL   val-saturated,
                       V-POS v-pos-not-last ],
           NONLOCAL  no-nonlocal ] ].

root-wh-question := sign & 
[ SYNSEM synsem-match &
         [ LOCAL.CAT [ HEAD  head-super-verb & [ FORM-VERB form-verb-fin ],
                       VAL   val-saturated,
                       V-POS v-pos-second ],
           NONLOCAL  no-slash-rel & 
                     [ QUE agr-wh ] ] ].


; This root obliges the subject to still have one item, to allow a sentence like: 'das getraenk trinken'. 
root-inf-final := sign & 
[ SYNSEM synsem-match &
         [ LOCAL.CAT [ HEAD  head-super-verb & [ FORM-VERB form-verb-inf ],
                       VAL   [ SUBJ   < synsem >,
                               SUBCAT < >,
                               XCOMP  < > ],
                       V-POS v-pos-last ],
           NONLOCAL  no-nonlocal ] ].

root-psp-final := sign & 
[ SYNSEM synsem-match &
         [ LOCAL.CAT [ HEAD  head-super-verb & [ FORM-VERB form-verb-psp ],
                       VAL   [ SUBJ   < synsem >,
                               SUBCAT < >,
                               XCOMP  < > ],
                       V-POS v-pos-last ],
           NONLOCAL  no-nonlocal ] ].

root-np := sign & 
[ SYNSEM [ LOCAL.CAT [ HEAD     head-super-noun & [ AGR agr-match & [ CASE case-nom-dat-acc ] ],
                       VAL      val-saturated,
                       LINEAR-N linear-n-can-pre ],
           NONLOCAL  no-nonlocal ] ].

; MOD synsem-match needed to include normal PPs and diff-CPPs, and exclude eq-CPPs. 
root-pp := sign & 
[ SYNSEM [ LOCAL.CAT [ HEAD head-super-adposition & [ MOD synsem-match ],
                       VAL  val-saturated ],
           NONLOCAL  no-nonlocal ] ].

root-ds := sign & 
[ SYNSEM [ LOCAL.CAT [ HEAD head-ds,
                       VAL  val-saturated ],
           NONLOCAL  no-nonlocal ] ].