;;; -*- Mode: TDL; Coding: euc-jp -*-

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;        file: adjadv-lex.tdl
;;;      module: lexicon
;;;     version: %I%
;;;  written by: Melanie Siegel
;;; last update: 
;;;  updated by:
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; author            | date    | modification
;;; ------------------|---------|---------------------------------------------
;;; Melanie Siegel    |         | Francis Bond (FCB)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; FCB prefers to think of this as precise-lex.tdl
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


; (MS 2005-05-11) This is the topic marker that replaces case particles,
; such that we have massive ambiguity whenever case particles occur. 
; (MS 2005-05-13) It sets empathy to the entity it attaches to.
; (MS 2005-09-22) It sets empathy to the entity it attaches to, only
; when it is case ga! If it is a case of object topicalization, the 
; empathy is rather set to the sentence subject (see Watanabe 2000)


wa-case-ga := case-p-lex-np-topic-ga & 
 [SYNSEM.LOCAL.CAT.HEAD.PTYPE wa,
  ORTH <! "は" !>].

wa-case-wo := case-p-lex-np-topic-wo & 
 [SYNSEM.LOCAL.CAT.HEAD.PTYPE wa,
  ORTH <! "は" !>].

;;; FIXME add something tha says this is "mo" in the semantics
mo-case-ga := case-p-lex-np-topic-ga & 
 [SYNSEM.LOCAL.CAT.HEAD.PTYPE mo,
  ORTH <! "も" !>].

mo-case-wo := case-p-lex-np-topic-wo & 
 [SYNSEM.LOCAL.CAT.HEAD.PTYPE mo,
  ORTH <! "も" !>].



;(CH 2005-03-10)
; solution to parse 「ボールを進んで打つ」「ボールを続けて打つ」.
; I'm not sure if this is correct...

te-adjunct := te-adjunct-lex-t &
             [SYNSEM.LKEYS.KEYREL.PRED '_te_adjunct_rel,
              ORTH <! "て" !>].

de-adjunct := te-adjunct-lex-d &
             [SYNSEM.LKEYS.KEYREL.PRED '_te_adjunct_rel,
              ORTH <! "で" !>].



; (FCB and CH 2005-03-12) for complement suru 
; (do-parse-tty "彼 が 鈍 を 金 に し た") "he made lead into gold"
; SOC  subject-object-complement

; (MS 2005-05-24) these add a lot of ambiguity as well, as for example
; in 食べなさい

suru-soc-noun-stem := v-soc-noun-kurusuru-stem-lex &
[SYNSEM.LKEYS [KEYREL [PRED '_suru_v_soc_rel]],
ORTH <! "する" !>].

suru-soc-adv-stem := v-soc-adv-kurusuru-stem-lex &
[SYNSEM.LKEYS [KEYREL [PRED '_suru_v_soc_rel]],
ORTH <! "する" !>].

nasaru-soc-noun-stem := v-soc-noun-c2-shon-stem-lex &
[SYNSEM.LKEYS [KEYREL [PRED '_nasaru_v_soc_rel]],
ORTH <! "なさる" !>].

nasaru-soc-adv-stem := v-soc-adv-c2-shon-stem-lex &
[SYNSEM.LKEYS [KEYREL [PRED '_nasaru_v_soc_rel]],
ORTH <! "なさる" !>].