;;; -*- Mode: tdl; Coding: utf-8; -*-
;;;
;;;  Copyright Emily M. Bender 2003-2005
;;;  All Rights Reserved.
;;;  No use or redistribution without permission.
;;;
;;;  mal-inflr.tdl
;;;
;;;  mal inflectional lr instances for Arboretum project.
;;;

;; Disagreement rules, one for each direction.  Pair synsem with
;; "wrong" forms: The dog bark/the dogs barks.
;;
mal_non_third_sg_fin_verb_infl_rule :=
%suffix (!s !ss) (!ss !ssses) (ss sses) (!ty !ties) (ch ches) (sh shes) (x xes) (z zes)
lex_rule_infl_affixed &
[ ROBUST +,
  NO-AFF +,
  SYNSEM.LOCAL non_third_sg_fin_verb ].

mal_third_sg_fin_verb_infl_rule := lex_rule_infl_affixed &
[ ROBUST +,
  NO-AFF -,
  ORTH #stem,
  DTR  [ ORTH #stem ],
  SYNSEM.LOCAL third_sg_fin_verb ].

;; DPF 10-May-04 - We take plural marking on noun as intended (not to be
;; corrected), so only have one mal infl-rule for nouns to correct 
;; 'two dog bark' to 'two dogs bark'.  We will need a statistical preference 
;; mechanism to choose one of the two possible corrections for 'dog bark':
;; either 'dogs bark' or 'a/the dog barks'.  But have to have both, since
;; 'he bark' should presumably get corrected to 'he barks' (not 'they bark').

mal_plur_noun_infl_rule := lex_rule_infl_affixed &
[ ROBUST +,
  NO-AFF -,
  ORTH #stem,
  DTR  [ ORTH #stem,
         SYNSEM.LOCAL.CAT.HEAD.KEYS.KEY norm_nom_rel ],
  SYNSEM.LOCAL plur_noun ].

mal_mass_noun_infl_rule :=
%suffix (!s !ss) (!ss !ssses) (ss sses) (!ty !ties) (ch ches) (sh shes) (x xes) (z zes)
lex_rule_infl_affixed &
[ ROBUST +,
  NO-AFF +,
  SYNSEM.LOCAL mass_noun ].