;;; Hey, emacs(1), this is -*- Mode: TDL; Coding: utf-8; -*- got it?

;;; Author(s):
;;; 2008 Berthold Crysmann

message_mtr := monotonic_mtr &
[ INPUT.RELS < [ LBL #h0, ARG0 #e1, MARG #h2, TPC #u3, PSV #u4 ] >,
  OUTPUT.RELS < [ LBL #h0, ARG0 #e1, MARG #h2, TPC #u3, PSV #u4 ] > ].

message_omtr := message_mtr & optional_mtr.

scopal_mod_mtr :=
		 monotonic_mtr & 
		 [CONTEXT [HCONS <qeq & [HARG #harg,
					 LARG #larg1],
				  qeq & [HARG #harg2,
					 LARG #larg]>,
			   RELS <[LBL #larg1,
				  ARG0 e, 
				  ARG1 #harg1,
				  ARG2 a],
				 [LBL #larg2,
				  ARG0 e, 
				  ARG1 #harg2,
				  ARG2 a],
				 [MARG #harg ]>],
		  INPUT [HCONS <qeq & [HARG #harg,
				       LARG #larg2],
				qeq & [HARG #harg1,
				       LARG #larg]
				>,
			 RELS <>],
		  OUTPUT [HCONS <qeq & [HARG #harg1,
					LARG #larg2]>,
			  RELS <>]].

scopal_mod_omtr :=
		  scopal_mod_mtr &		 
		  monotonic_omtr.

msg_mtr :=
	  monotonic_mtr.

msg_omtr := 
	    msg_mtr & monotonic_omtr.


dofw_mtr :=  
	     monotonic_mtr &
	     [INPUT.RELS <[PRED "de:dofw_rel",
			   LBL #l,
			   ARG0 #0]>,
	      OUTPUT.RELS <[PRED dofw_rel,
			   LBL #l,
			   ARG0 #0]>].
	      
			     
subordination_mtr := 
	       monotonic_mtr &
	       [INPUT.RELS <[LBL #l,
			     ARG0 #0,
			     MAIN #m & e,
			     SUBORD #s]>,
		CONTEXT.RELS <[PRED "~_[avp]_",
			       LBL #larg,
			       ARG0 #m]>,
		OUTPUT [RELS <[LBL #l,
			     ARG0 #0,
			     ARG1 #harg & h,
			     ARG2 #s]>,
			HCONS < qeq & [HARG #harg,
				       LARG #larg]>] ].

subordination_omtr  :=
		      subordination_mtr &
		      monotonic_omtr.

message_matrix_convert_mtr := 
			     msg_mtr &
			     [INPUT [LTOP #u,
				     RELS <[ARG0 #0],
					   [LBL #u,
					    MARG #h,
					    ARG0 #0,
					    TPC #tpc & u,
					    PSV #psv & u]
					   >,
				     HCONS < qeq & [HARG #h]>],
			      FLAGS.EQUAL <#tpc,#psv>,
			      OUTPUT [RELS < [] >,
				      HCONS <>]
				    ].


message_relc_convert_mtr := 
			     msg_mtr &
			     [INPUT [RELS <[PRED #pred,
					    ARG0 #0],
					   [LBL #u,
					    MARG #h,
					    ARG0 #0,
					    TPC #tpc & u,
					    PSV #psv & u]
					   >,
				     HCONS < qeq & [HARG #h]>],
			      FLAGS.EQUAL <#tpc,#psv>,
			      OUTPUT [RELS < [PRED #pred,
					      ARG0 #0 & [SF prop],
					      LBL #u] >,
				      HCONS <>]
				    ].

message_subord_convert_mtr := msg_mtr &
			      [INPUT [RELS <[ARG0 #0],
					    [LBL #u,
					     MARG #h,
					     ARG0 #0,
					     TPC #tpc & u,
					     PSV #psv & u]
					    >,
				      HCONS < qeq & [HARG #h,
						     LARG #l]>],
			       FLAGS.EQUAL <#tpc,#psv>,
			       OUTPUT [RELS < [ARG0.SF prop] >,
				       HCONS < qeq & [HARG #u,
						      LARG #l]>]].


hundred_convert_mtr := monotonic_mtr &
		   [INPUT.RELS <[PRED "de:card_rel",
				 LBL #h,
				 ARG0 #0,
				 ARG1 #1 ] >,
		    OUTPUT.RELS <[PRED "de:card_rel",
				  LBL #l,
				  ARG1 #1,
				  CARG string,
				  ARG0 e ],
				 [PRED "de:times_rel",
				 LBL #h,
				 ARG0 #0,
				 ARG1 #1,
				 ARG2 #l,
				 ARG3 #r],
				[PRED "de:card_rel",
				 CARG "100",
				 LBL #r,
				 ARG1 #1,
				 ARG0 e ]>].



head-switch_isect_gerund_mtr := monotonic_mtr &
				[ INPUT.RELS < [ LBL #h0, 
						 ARG0 e, 
						 ARG1 #e1 ],
					       [ LBL #h0, 
						 PRED #pred, 
						 ARG0 #e1, 
						 ARG1 #u1, 
						 ARG2 #u2, 
						 ARG3 #u3,
						 ARG4 #u4
						     ] >,
				  OUTPUT [RELS < [ARG0 #e1,
						  LBL #h0,
						  ARG1 h & #harg],
						 [ LBL #larg, 
						   PRED #pred,
						   ARG0 e & [TENSE untensed,
							     PROG +], 
						   ARG1 #u1, 
						   ARG2 #u2, 
						   ARG3 #u3,
						   ARG4 #u4
						       ]
						 >,
					  HCONS < qeq & [HARG #harg,
							 LARG #larg]>]].



compound_split_mtr :=
		       monotonic_mtr & 
		       [INPUT.RELS <[LBL #l0,
				     ARG0 #x0]>,
			OUTPUT [RELS <[LBL #l2,
				       ARG0 #x1 & [NUM sg, PERS 3]],
				      [LBL #l0,
				       ARG0 #x0],
				      [PRED "de:compound_rel",
				       LBL #l0,
				       ARG1 #x0,
				       ARG2 #x1],
				      [PRED "de:udef_q_rel",
				       LBL h,
				       ARG0 #x1,
				       RSTR #l1,
				       BODY h]>,
				HCONS <qeq & [HARG #l1,
					      LARG #l2]>]].

day-daytime_split_mtr :=
		       monotonic_mtr & 
		       [INPUT.RELS <[LBL #l0,
				     ARG0 #x0]>,
			OUTPUT [RELS <[PRED "de:dofw_rel",
				       LBL #l2,
				       ARG0 #x1 & [NUM sg, PERS 3]],
				      [LBL #l0,
				       ARG0 #x0],
				      [PRED "de:of_p_rel",
				       LBL #l0,
				       ARG1 #x0,
				       ARG2 #x1],
				      [PRED "de:def_implicit_q_rel",
				       LBL h,
				       ARG0 #x1,
				       RSTR #l1,
				       BODY h]>,
				HCONS <qeq & [HARG #l1,
					      LARG #l2]>]].