;;; Hey, emacs(1), this is -*- Mode: TDL; Coding: utf-8; -*- got it?

;;;
;;; finally, perform some post-core fix-up: make sure variable equations are
;;; being propagated, delete transfer-internal meta EPs, et al.
;;;

equate_ditch_cf := elision_mtr &
[ INPUT.RELS < [ PRED "equate" ] > ].

mark_ditch_cf := elision_mtr &
[ INPUT.RELS < [ PRED "mark" ] > ].

;;;
;;; _fix_me_
;;; see comments on `adjective_prp_participle_mtr' definition for the rationale
;;; behind the following mechanism.                             (29-may-06; oe)
;;;
progressive_cf := monotonic_mtr &
[ INPUT.RELS < [ LBL #h4 & h, ARG0 #e2 & e ],
               [ PRED "progressive", LBL #h4, ARG0 #e2 ] >,
  OUTPUT.RELS < +copy+ & [ ARG0 [ PROG +, TENSE untensed ] ] >,
  FLAGS.EQUAL < #h4, #e2 > ].

progressive_ditch_cf := elision_mtr &
[ INPUT.RELS < [ PRED "progressive" ] > ].

;;;
;;; something in the same spirit, for `n+n_n+p+q+n_sg_mtr' et al.
;;;
sg_cf := monotonic_mtr &
[ INPUT.RELS < [ PRED "~_n_", LBL #h0 & h, ARG0 #x1 & x ],
               [ PRED "sg", LBL #h0, ARG0 #x1 ] >,
  OUTPUT.RELS < +copy+ & [ ARG0 [ PERS 3, NUM sg, GRIND - ] ] >,
  FLAGS.EQUAL < #h0, #x1 > ].

sg_ditch_cf := elision_mtr &
[ INPUT.RELS < [ PRED "sg" ] > ].

pl_cf := monotonic_mtr &
[ INPUT.RELS < [ PRED "~_n_", LBL #h0 & h, ARG0 #x1 & x ],
               [ PRED "pl", LBL #h0, ARG0 #x1 ] >,
  OUTPUT.RELS < +copy+ & [ ARG0 [ PERS 3, NUM sg, GRIND - ] ] >,
  FLAGS.EQUAL < #h0, #x1 > ].

pl_ditch_cf := elision_mtr &
[ INPUT.RELS < [ PRED "pl" ] > ].

reflexive_poss_cf := monotonic_omtr &
[ CONTEXT.RELS < [ PRED pron_rel, LBL #h0, ARG0 #x1 ],
                 [ PRED identity_rel, LBL #h0, ARG1 #x1 ],
                 [ PRED poss_rel, LBL #h3, ARG1 #x1, ARG2 #x2 ] >,
  FILTER.RELS < [ PRED "_own_a_1_rel", LBL #h3, ARG0 e_untensed, ARG1 #x2 ] >,
  OUTPUT.RELS < [ PRED "_own_a_1_rel", LBL #h3,
                  ARG0 e_untensed, ARG1 #x2 ] > ].