;;; Hey, emacs(1), this is -*- Mode: TDL; Coding: utf-8; -*- got it?


adj*n_no := exhaustive_mtr &
[ INPUT [ LTOP #h0,
          RELS < [ PRED "~_a_", ARG0 #e2 & e],
                 [ PRED "~_n_", LBL #h3, ARG0 #x3 & x & [ NUM sg ]],
                 [ PRED "unspec_rel", LBL #h3, ARG1 #x3, ARG2 #e2 ],
                 [ PRED "unknown_rel", LBL #h2, ARG #x3 & x ],
                 [ ARG0 #x3, RSTR #h4 ] >,
          HCONS < qeq & [ HARG #h0, LARG #h2 ],
                  qeq & [ HARG #h4, LARG #h3 ] > ],
  OUTPUT.RELS < +copy+, +copy+ >,
  FLAGS.EQUAL < #x3, #e2 > ].

v*n_no := exhaustive_mtr &
[ INPUT [ LTOP #h0,
          RELS < [ PRED "~_v_", ARG0 #e7 & e ],
                 [ PRED "~_n_", LBL #h5, ARG0 #x3 & x & [ NUM sg ] ],
                 [ PRED "unknown_rel", LBL #h2, ARG #x3 ],
                 [ PRED "unspec_rel", ARG1 #x3, ARG2 #e7 ],
                 [ ARG0 #x3, RSTR #h4 ] >,
          HCONS < qeq & [ HARG #h0, LARG #h2 ],
                  qeq & [ HARG #h4, LARG #h5 ] > ],
  OUTPUT.RELS < +copy+, +copy+ >,
  FLAGS.EQUAL < #x3, #e7 > ].

;;;
;;; _fix_me_
;;; given our current flat analysis of compounds, there is no way of ensuring
;;; the right order among two modifiers in the output, e.g. for `fotturrute', 
;;; we risk getting `tur' + `fot' + `rute' :-{.                 (15-oct-06; oe)
;;;
n*n*n_no := exhaustive_mtr &
[ INPUT [ LTOP #h0,
          RELS < [ PRED "~_n_", LBL #h9, ARG1 #x10 ],
                 [ PRED "~_n_", LBL #h7, ARG1 #x8 ],
                 [ PRED "~_n_", LBL #h5, ARG0 #x3 & x & [ NUM sg ] ],
                 [ PRED "unknown_rel", LBL #h2, ARG #x3 & x ],
                 [ PRED "unspec_rel", ARG1 #x3, ARG2 #x8 ],
                 [ PRED "unspec_rel", ARG1 #x3, ARG2 #x10 ],
                 [ ARG0 #x10, RSTR #h11 ],
                 [ ARG0 #x3, RSTR #h4 ],
                 [ ARG0 #x8, RSTR #h6 ] >,
          HCONS < qeq & [ HARG #h0, LARG #h2 ],
                  qeq & [ HARG #h11, LARG #h9 ],
                  qeq & [ HARG #h4, LARG #h5 ],
                  qeq & [ HARG #h6, LARG #h7 ] > ],
  OUTPUT.RELS < +copy+, +copy+, +copy+ >,
  FLAGS.EQUAL < #x3 > ].

n*n_no := exhaustive_mtr &
[ INPUT [ LTOP #h0,
          RELS < [ PRED "~_n_", LBL #h7, ARG1 #x8 ],
                 [ PRED "~_n_", LBL #h5, ARG0 #x3 & x & [ NUM sg ] ],
                 [ PRED "unknown_rel", LBL #h2, ARG #x3 & x ],
                 [ PRED "unspec_rel", ARG1 #x3, ARG2 #x8 ],
                 [ ARG0 #x3, RSTR #h4 ],
                 [ ARG0 #x8, RSTR #h6 ] >,
          HCONS < qeq & [ HARG #h0, LARG #h2 ],
                  qeq & [ HARG #h4, LARG #h5 ],
                  qeq & [ HARG #h6, LARG #h7 ] > ],
  OUTPUT.RELS < +copy+, +copy+ >,
  FLAGS.EQUAL < #x3 > ].


adjective_no := exhaustive_mtr &
[ INPUT [ LTOP #h0,
          RELS < [ PRED "~_a_", ARG1 #u4 ],
                 [ PRED "unknown_rel", LBL #h2, ARG0 #e3, ARG #u4 ] >,
          HCONS < qeq & [ HARG #h0, LARG #h2 ] > ],
  OUTPUT.RELS < +copy+ > ].


noun_no := exhaustive_mtr &
[ INPUT [ LTOP #h0,
          RELS < [ PRED "~_n_", LBL #h5, ARG0 #x3 & [ NUM sg ] ],
                 [ PRED "unknown_rel", LBL #h2, ARG #x3 & x ],
                 [ ARG0 #x3, RSTR #h4 ] >,
          HCONS < qeq & [ HARG #h0, LARG #h2 ],
                  qeq & [ HARG #h4, LARG #h5 ] > ],
  OUTPUT.RELS < +copy+ >,
  FLAGS.EQUAL < #x3 > ].