; -*- Mode: TDL; Package: LKB; -*- 
; 
;;;
;;; `multi-word' transfer rules: typically things we should process before the
;;; `regular' transfer rules consume some of the pieces these rules require.
;;;  taken from oe -25-jan-04 -- db
;;;
;;; There are still some dinosaurs in this file (11-03) db.
;;;

turgåer-to-hiker_n_rel :=compound-to-noun_mtr  &
[  INPUT.RELS < [PRED "_tur_n_rel"] ,
 	 [ PRED "_gåer_n_rel" ], [PRED "unspec_rel" ], [PRED "udef_q_rel" ] >, 
OUTPUT.RELS <  [ PRED "_hiker_n_rel"  ] > ].

vareutvalget-to-selection-of_rel := compound-to-of_mtr &
[  INPUT.RELS < [PRED "_utvalg_n_rel"] ,
 	 [ PRED "_vare_n_rel" ], [PRED "unspec_rel" ] >, 
OUTPUT.RELS <  [ PRED "_of_p_sel_rel"  ],[PRED "_selection_n_rel"] ,
	[ PRED "_goods_n_rel"] > ].

tilbake_contxt_r_rel := monotonic_mtr  &
[ CONTEXT.RELS < [ PRED "_gå_v_rel",ARG0 #e1 ] >,
INPUT.RELS < [ PRED "_tilbake_r_rel", LBL#h0  ] >,
  OUTPUT [ RELS < [ PRED _back_p_rel, LBL #h0, 
                     ARG0  e_no_tense, ARG1 #e1 ] >]].

i-contxt-season_rel := monotonic_mtr  &
[ CONTEXT.RELS < [ PRED "_sommer_n_rel" ] >,
  INPUT.RELS < [ PRED "_i_p_rel",LBL #h, ARG0 #e, ARG1#e2, ARG2 #x ] >,
  OUTPUT.RELS <[ PRED unspec_loc_rel,LBL #h, ARG0 #e, ARG1#e2, ARG2 #x ]>].  



vassdrags-kilde  := monotonic_mtr &
[ INPUT.RELS < noun-relation & [ LBL #h1, PRED "_vassdrag_n_rel",
	 ARG0 #x1],noun-relation & [ LBL #h2, PRED "_kilde_n_rel",
		   ARG0 #x2],
		 arg012-relation & [ PRED "poss_rel", ARG1 #x1,
                 ARG2 #x2 ] >,
  OUTPUT.RELS <  noun-relation & [ LBL #h1, PRED "_watercourse_n_rel",
		   ARG0 #x1], arg01-relation & [ LBL #h2,
                PRED "_source_n_rel",ARG0 #x2, ARG1 #x1],  arg012-relation & 
		[ PRED _of_p_sel_rel, ARG1 u, ARG2 #x1 ] > ].

contxt-hund_n_rel := monotonic_mtr &
[ CONTEXT.RELS < [ PRED "unspec_rel", ARG2 #x1] >,
  INPUT.RELS <   [ LBL #h1,  PRED "_hund_n_rel", ARG0 #x1] >,
  OUTPUT.RELS < [  LBL #h1,  PRED "_dogsled_n_rel", ARG0 #x1] > ].


fjellet_n := monotonic_omtr &
[ CONTEXT [ RELS < [ PRED "def_rel", ARG0 #x1, RSTR #h2 ] >,
            HCONS < qeq & [ HARG #h2, LARG #h3 ] > ],
  INPUT.RELS < [ PRED "_fjell_n_rel", LBL #h3, 
                  ARG0 #x1 & [ NUM sg ] ] >,
  OUTPUT.RELS < [ PRED "_mountain_n_rel", LBL #h3, 
                   ARG0 #x1 & [ NUM pl ] ] > ].

epist-kunne_v := monotonic_omtr &
[ CONTEXT.RELS < [ PRED "_epist-ville_rel", ARG1 #h2 ] >,
  INPUT.HCONS < qeq & [ HARG #h2, LARG #h3 ] >,
  INPUT.RELS < [ PRED "_epist-kunne_rel", LBL #h3 ] >,
  OUTPUT.RELS <  > ].

ville-deletion := monotonic_mtr &
[ CONTEXT.RELS < [ PRED "_gi_v_rel" ] >,
  INPUT.HCONS <  [ HARG #hnd , LARG #lbl ] >,
  INPUT.RELS < [ PRED "root-kunne_rel", LBL #lbl, ARG1 #h ],
	[ PRED "root-ville_rel", LBL #h1,ARG0 #e, ARG1 #hnd] >,
  OUTPUT.RELS < [ PRED _could_v_rel, LBL#h1,ARG0 #e, ARG1 #h ]> ].


loan-to-gerund-rel := monotonic_omtr &
[CONTEXT.RELS < [ PRED "_forurensing_n_rel", ARG0 #x1 ]>,
INPUT.RELS < [ PRED "_bombing_n_rel", LBL #lbl, ARG0 #x2 ],
 [ PRED "_gi_v_rel", ARG0 #e1, LBL #h1, ARG1 #x2,
	ARG2 #x1],[ PRED "bare_div_q_rel", RSTR #h2],
	[ PRED "_i_p_rel", LBL #lbl,ARG1 #x2, ARG2 #x5  ] >,
 INPUT.HCONS < [ HARG #h2, LARG #lbl] >,
 OUTPUT.RELS <arg012-relation & [ PRED "_bomb_v_rel" , LBL #lbl,
	ARG0 e & #e1 ], [ PRED "_produce_v_rel", LBL #h1, ARG0 #e1, ARG1 #x3,
	ARG2 #x1],[ PRED prpstn_m_rel, LBL #h4, MARG #h5 ],
	[ PRED gerund_rel, LBL #lbl1, ARG0 #x3, ARG1 #h4 ],
arg012-relation & [ PRED _in_p_rel, LBL #lbl1, ARG1 #x3, ARG2 #x5],
quant-relation & [ PRED udef_q_rel, RSTR #h2, ARG0 #x3] >,
OUTPUT.HCONS < [ HARG #h2, LARG #lbl1],
 [ HARG #h5, LARG #lbl ] > ].



udef-for-bruk-av := monotonic_mtr &
[CONTEXT.RELS < [ PRED "_bruk-av_n_rel" , ARG0 #x, LBL #lbl] >,
 INPUT.RELS < [ PRED "udef_q_rel", ARG0 #x, RSTR #h1 ] >,
 INPUT.HCONS < [ HARG #h1, LARG #lbl ] >,
 OUTPUT.RELS < > ].

gå_pass_v_rel := arg012_v_omtr &
[ CONTEXT.RELS < [ PRED "_gjennom_p_rel", ARG0 #x1 ] >,
  INPUT.RELS < [ PRED "_gå_v_rel", ARG2 #x1 ] >,
  OUTPUT.RELS < [ PRED "_pass_v_1_rel" ] > ].


gå_take_v_rel := arg012_v_omtr &
[ CONTEXT.RELS < [ PRED "_rundtur_n_rel", ARG0 #x1 ] >,
  INPUT.RELS < [ PRED "_gå_v_rel", ARG2 #x1 ] >,
  OUTPUT.RELS < [ PRED "_take_v_1_rel" ] > ].

gå_take_v := arg012_v_omtr &
[ CONTEXT.RELS < [ PRED "_rute_n_rel", ARG0 #x1 ] >,
  INPUT.RELS < [ PRED "_gå_v_rel", ARG2 #x1 ] >,
  OUTPUT.RELS < [ PRED "_take_v_1_rel" ] > ].

ta-to-travel_v := monotonic_mtr &
[ CONTEXT.RELS < [ PRED "_båt_n_rel"],
  [ PRED "or_rel", ARG0 #x2] >,
  INPUT.RELS < [ PRED "_ta_v_rel", LBL #h1, ARG0 #e1, ARG1 #x1,ARG2 #x2] >,
  OUTPUT.RELS < [ PRED "_travel_v_rel", LBL #h1, ARG0 #e1, ARG1 #x1 ],
	[ PRED _by_p_rel,LBL #h1, ARG0 e, ARG1 #e1,ARG2 #x2] >,
  OUTPUT.INDEX #e2 ]. 

av_p_rel := monotonic_mtr &
[ CONTEXT.RELS < [ PRED "_forurensing_n_rel", ARG0 #x1 ] >,
INPUT.RELS < [ PRED "_av_p_rel", LBL #h1, 
                  ARG0 e & #e1, ARG1 e, ARG2 #x2 ] >,
  OUTPUT.RELS < [ PRED _of_p_rel, LBL #h1, 
                   ARG0 e & #e1, ARG1 #x1, ARG2 #x2 ] > ].



på_forhånd := monotonic_mtr &
[ INPUT [ RELS < [ PRED "_på_p_rel", LBL #h1,
                    ARG1 #e2, ARG2 #x3 ],
                  [ PRED "udef_q_rel",
                    ARG0 #x3, RSTR #h4 ],
                  [ PRED "_forhånd_n_rel", LBL #h5,
                    ARG0 #x3 ] >,
          HCONS < qeq & [ HARG #h4, LARG #h5 ]> ],
  OUTPUT.RELS < [ PRED "_in+advance_r_rel", LBL #h1, ARG1 #e2 ] > ].



possdef := quantifier_mtr & 
[ CONTEXT.RELS < [ PRED "poss_rel", LBL #lbl] >,
  CONTEXT.HCONS < [HARG #hdl, LARG #lbl] >,
  INPUT.RELS < [ PRED "def_rel", RSTR #hdl ] >,
  OUTPUT.RELS < [ PRED def_explicit_q_rel ] > ].

sti-quant_mm := monotonic_mtr & 
[ CONTEXT.RELS < [ PRED "_sti_n_rel", ARG0 #x4, LBL #lbl ],
 [ PRED "_sørøstlig_j_rel", ARG1 #x3] >,
 CONTEXT.HCONS < [ HARG #h3, LARG #lbl] >,
  INPUT.RELS < [ PRED "udef_q_rel", ARG0 #x4, LBL # h2, RSTR #h3] >,
  OUTPUT.RELS < [ PRED _the_q_rel , LBL #h2, ARG0 #x4, RSTR #h3],
  arg012-relation & [ PRED unspec_loc_rel, ARG1 #x4, ARG2 #x3] > ].
 
 

free-relative-quant_mm := monotonic_mtr &
[ CONTEXT.RELS < [ PRED "place_rel",ARG0 #x1, LBL #lbl],
	[ PRED "_ta_v_rel", ARG0 #e1, LBL #h4]  >,
  INPUT.RELS < [ PRED "def_q_rel", ARG0 #x1, LBL # h2, RSTR #h3],
	[ PRED "_der_rel", ARG1 #x1] >,
  OUTPUT.RELS < [ PRED free_relative_ever_q_rel, LBL #h2, ARG0 #x1, RSTR #h3]>,
 OUTPUT.HCONS < [ HARG #h3, LARG #lbl] > ].


sørøstlig-to-towards-southeast :=  monotonic_mtr &
[ CONTEXT.RELS < [ PRED "_sti_n_rel", ARG0 #x2 ] >,
  INPUT.RELS < [ PRED "_sørøstlig_j_rel", LBL #lbl, ARG1 #x1 ], 
	[ PRED "_i_p_rel", ARG2 #x1],[ PRED "_retning_n_rel",
	ARG0 #x1, LBL #lbl] >,
  OUTPUT.RELS < arg012-relation & [ PRED _towards_p_rel,ARG1 #x2, ARG2 #x3 ],
	arg01-relation & [ PRED "_southeast_n_rel",ARG0 #x3, LBL #lbl2 ],
	quant-relation & [ PRED _the_q_rel, RSTR #h ] >,
  OUTPUT.HCONS < [ HARG #h, LARG #lbl2 ] > ].  





forsiktig-med := monotonic_mtr &
[ CONTEXT.RELS < [ PRED "_bruk-av_n_rel" , ARG0 #x1],
	[ PRED "_ild_n_rel", ARG0 #x2 ]  >,
  INPUT.RELS < [ PRED "_forsiktig-med_j_rel", ARG2 #x1 ] >,
  OUTPUT.RELS < [ PRED "_careful_j_rel", ARG2 #x2, LBL #h1 ], 
arg012-relation &
	[ PRED _with_p_sel_rel , ARG0 e, ARG1 u, ARG2 #x2, LBL #h1] > ].



udef-for-and_rel := quantifier_omtr  &
[CONTEXT.RELS < [PRED "and_rel" , ARG0 #x, LBL #lbl, L-INDEX #x1],
	[ PRED "_skog_n_rel", ARG0 #x1] >,
 CONTEXT.HCONS < [ HARG #h1, LARG #lbl] >,
 INPUT.RELS < [ PRED "udef_q_rel", ARG0 #x, RSTR #h1 ] >,
 OUTPUT.RELS < [ PRED _the_q_rel] > ].

skog_og_mark := monotonic_mtr &
[ CONTEXT.HCONS < qeq & [ HARG #h2, LARG #h3 ] >,
  INPUT [ RELS < [ PRED "udef_q_rel", LBL #h0,
                    ARG0 #x1, RSTR #h2, BODY #h10 ],
                  [ PRED "and_rel", LBL #h3, 
                    ARG0 #x1, L-INDEX #x4, R-INDEX #x5 ],
                  [ PRED "udef_q_rel", ARG0 #x4, RSTR #h6 ],
                  [ PRED "_skog_n_rel", LBL #h7, ARG0 #x4 ],
                  [ PRED "udef_q_rel", ARG0 #x5, RSTR #h8 ],
                  [ PRED "_mark_n_rel", LBL #h9, ARG0 #x5 ] >,
          HCONS < qeq & [ HARG #h6, LARG #h7 ], 
                   qeq & [ HARG #h8, LARG #h9 ] > ],
  OUTPUT [ RELS < [ PRED _the_q_rel, LBL #h0,
                     ARG0 #x1, RSTR #h2, BODY #h10 ],
                   [ PRED "_backcountry_n_rel", LBL #h3, 
                     ARG0 #x1 & [ PERS 3, NUM sg ] ] > ] ].

 generic-nom_rel:= arg0_mtr &
[ CONTEXT.RELS < [PRED "noen_q_rel", RSTR #2] >,
  CONTEXT.HCONS < [ HARG #2, LARG #3] >,
  INPUT.RELS < [ PRED "generic-nom_rel", LBL #3 ] >,
  OUTPUT.RELS < [ PRED generic_nonpro_rel ] > ].

;; annen will not always be an adjective: "andre sunne grønnsaker"
;; we therefore would like to contextualize the transfer of 'annen'
;; --write generel rule when time --

contxt-annen := monotonic_mtr &
[ CONTEXT.RELS < [ LBL #lbl, ARG0 #x4, PRED "_gåer_n_rel" ] >,
  INPUT.RELS < quant-relation & [ PRED "annen_q_rel", ARG0 #x4,
  					RSTR #h6 ] >,
  INPUT.HCONS < [HARG #h6, LARG #lbl] >,
  OUTPUT.RELS < arg01-relation & [ LBL #lbl, ARG0 e, ARG1 #x4,
                                 PRED "_other_j_rel"] >].

contxt-annen := monotonic_mtr &
[ CONTEXT.RELS < [ LBL #lbl, ARG0 #x4, PRED "_stoff_n_rel" ] >,
  INPUT.RELS < quant-relation & [ PRED "annen_q_rel", ARG0 #x4,
  					RSTR #h6 ] >,
  INPUT.HCONS < [HARG #h6, LARG #lbl] >,
  OUTPUT.RELS < arg01-relation & [ LBL #lbl, ARG0 e, ARG1 #x4,
                                 PRED "_other_j_rel"] >].

samme_q_rel := monotonic_mtr &
[ CONTEXT.RELS < [ PRED "_dag_n_rel", ARG0 #x1]>,
  INPUT.RELS < [ PRED "samme_q_rel",LBL #h, ARG0 #x1, RSTR #h2 ] >,
  OUTPUT.RELS < [  PRED _the_q_rel, LBL #h, ARG0 #x1, RSTR #h2],
                 arg01-relation & [ PRED "_same_j_rel",ARG1 #x1 ] > ]. 

compound-to-noun :=monotonic_mtr &
[ INPUT.RELS < [ LBL #lbl,  ARG0 #x1, PRED "_tur_n_rel"  ],
  	 	 [ LBL #lbl3,ARG0 #x4, PRED "_gåer_n_rel" ],
  	 [LBL #lbl3, PRED "unspec_rel", ARG0 e, ARG1 #x4, ARG2 #x1],
          quant-relation & [PRED "udef_q_rel",ARG0 #x1, RSTR #h4] >,
  INPUT.HCONS < [ HARG #h4, LARG #lbl] >,
  OUTPUT.RELS < arg0-relation & [  ARG0 #x4, PRED "_hiker_n_rel" ]  > ].




overfor-to-for_rel := monotonic_mtr &
[CONTEXT.RELS < [ PRED"_hensyn_n_rel", LBL #h1, ARG0 #x2 ] >,
 INPUT.RELS < [ PRED "_overfor_p_rel", ARG2 #x1, ARG0 #e ]>, 
  OUTPUT.RELS < [   PRED _for_p_rel, LBL #h1, ARG2 #x1 , ARG1 #x2, ARG0 #e]
 > ]. 

visehensyntil-considerate-of_rel :=  monotonic_mtr &
[ INPUT.RELS < [ LBL #h1, PRED "_vise-hensyn-til_v_rel",
                   ARG0 #e, ARG1 #x1, ARG2 #x3  ],
	[ LBL #h1, PRED "_til_p_sel_rel", ARG2 #x3 ],
	[ PRED "_hensyn_n_sel_rel", ARG0 #x4,LBL #h3],
	[PRED "bare_div_q_rel", ARG0 #x4, RSTR #h2] >,
   INPUT.HCONS < [ HARG #h2, LARG #h3 ] >,
   OUTPUT.RELS < [  LBL #h1, PRED "_considerate_j_rel",  
                  ARG0 #e, ARG1 #x1, ARG2 #x3 ],
arg012-relation & [ LBL #h1, PRED _of_p_sel_rel,ARG0 e, ARG2 #x3 ]  > ].

noun-add-quantifier+adj_mtr :=monotonic_mtr &
[ CONTEXT.RELS < [ PRED"annen_q_rel", RSTR #h2, ARG0 #x1] >,
  INPUT.HCONS < [ HARG #h2, LARG #h1] >, 
  INPUT.RELS < [ LBL #h1, ARG0 #x1, PRED "_boss_n_rel" ] >,
  OUTPUT.RELS < [ LBL #h1, ARG0 #x1,PRED "_litter_n_rel" ],
               bare_div_q_rel & [ARG0 #x1, RSTR #h3, PRED bare_div_q_rel],
               arg01-relation & [ LBL #h1, ARG0 e, ARG1 #x1,
                                 PRED "_other_j_rel"]>,
  OUTPUT.HCONS < [ HARG #h3, LARG #h1  ] >,
  OUTPUT.LTOP #h1 ].





;; in norgram neg_rel as well as imp_rel qeq the main verb.
neg-imperative_m := monotonic_omtr &
[ CONTEXT.RELS < [ PRED"_kaste_v_rel", LBL #h1],
	[ PRED"_neg_r_rel", ARG1 #h3, LBL #h2 ] >,
  INPUT.HCONS < [ HARG #h4, LARG #h1 ],[ HARG #h3, LARG #h1]  >,
  INPUT.RELS <[ PRED "imp_m_rel", MARG #h4, LBL #h5 ] >, 
  OUTPUT.RELS < [ PRED imp_m_rel , MARG #h4, LBL #h5 ]  >,
  OUTPUT.HCONS < [ HARG #h4, LARG #h2 ], [ HARG #h3, LARG #h1] > ].




top-handle-fix :=  monotonic_mtr &
[ CONTEXT.RELS < [ PRED "prpstn_m_rel", LBL #h4] >,
  OUTPUT.LTOP #h2,
  CONTEXT.LTOP #h0,
  INPUT.RELS < [ PRED "but_disc_rel"], 
	[ PRED "int_m_rel", LBL #h0] >,
  OUTPUT.RELS < message & [ PRED prpstn_m_rel, LBL #h2, MARG # h3],
	[ PRED "_but_r_rel", ARG1 #h1, LBL #lbl], [ PRED int_m_rel, MARG #h4,
	LBL #h1] >,
  OUTPUT.HCONS < [ HARG #h3, LARG #lbl] > ].


norgram-modal-relinking := monotonic_mtr &
[CONTEXT.RELS < [ PRED "_gjøre_v_rel", LBL #lbl ] >, 
 INPUT.RELS < [ PRED "_root-skulle_v_rel", ARG0 #e1],
[ PRED"prpstn_m_rel", MARG #h2] >,
 INPUT.HCONS < [ HARG #h2, LARG #lbl ]>,
 OUTPUT.RELS < arg01-relation & [ PRED _can_v_rel, ARG0 #e1,
	ARG1 #h3] >,
 OUTPUT.HCONS < [ HARG #h3, LARG #lbl] > ].


leir_n_sel := monotonic_mtr &
[ CONTEXT.RELS < [ PRED "_slå-leir_v_rel"] >,
  INPUT.RELS < [ PRED "_leir_n_sel_rel", LBL #lbl, ARG0 #x1 ],
	[ PRED "bare_sg_q_rel", RSTR #h1, ARG0 #x1] >,
  INPUT.HCONS < [HARG #h1, LARG #lbl] >,
  OUTPUT.RELS < > ].


lørdagsopen-to-open-on := monotonic_mtr &
[ CONTEXT.RELS <[ PRED "named_rel", CARG "Turlaget", ARG0 #x1] >,
  INPUT.RELS < 	arg01-relation & [ PRED "_lørdagsåpen_r_rel", ARG1 #e, LBL #h1],
	arg012-relation & [ PRED "_på_p_rel", ARG2 #x1,ARG1 #x0],
 arg0-relation & [ ARG0 #x0, LBL #lbl ], 
	quant-relation & [ ARG0 #x0, RSTR #hnd ]>,
  INPUT.HCONS < [ HARG #hnd, LARG #lbl] >,
  OUTPUT.RELS < arg01-relation & [ PRED "_open_j_rel",LBL #h1,
	ARG0 #e, ARG1 #x1 ],
	dofw-relation & [ PRED dofw_rel,ARG0 #x3, ARG1 u, CARG "sat",
	 LBL #lbl],
 	arg012-relation & [ PRED _on_p_temp_rel, ARG1 #e, ARG2 #x3, LBL #h1],
	quant-relation & [PRED bare_div_q_rel, ARG0 #x3, RSTR #h2] >,
   OUTPUT.HCONS < [HARG #h2, LARG #lbl] >  ].



mot-on-the-way :=  monotonic_mtr &
[ CONTEXT.RELS < [ CARG "Solheimslien", ARG0 #x1], 
	[ PRED "_følge_v_rel", LBL #lbl, ARG0 #e4] >,
  INPUT.RELS < arg012-relation & [ PRED "_mot_p_rel", ARG2 #x1], 
   message &[ PRED "prpstn_m_rel", MARG #h1, LBL #h0] >,
  INPUT.HCONS < [HARG #h1, LARG #lbl] >,
  OUTPUT.RELS <  [ PRED _on_p_rel , LBL #lbl2,ARG0 e,
	ARG1 #e4, ARG2 #x2 ], 
  arg01-relation &[ PRED "_way_n_rel", ARG0 #x2, ARG1 #x1, LBL #lbl3 ],
  arg012-relation & [ PRED _to_p_sel_rel, ARG2 #x1,ARG0 e, LBL #lbl3],
  quant-relation & [ PRED _the_q_rel, RSTR #h3, ARG0 #x2],	
	[ PRED imp_m_rel, MARG #h2 , LBL #h0] >,
  OUTPUT.HCONS < [HARG #h2, LARG #lbl ], [ HARG #h3, LARG #lbl3]  >,
  OUTPUT.INDEX e & #e1 ].

følges-to-follow_v_rel := monotonic_mtr &
[ INPUT.RELS <  [ LBL #h, PRED "_følge_v_rel", ARG0 #e, ARG2 #x  ] >,
  OUTPUT.RELS <  [ LBL #h, PRED "_follow_v_1_rel", ARG0 #e, ARG1 #x2, ARG2 #x],
arg0-relation & [ LBL #lbl, PRED pron_rel, ARG0 x & #x2], quant-relation  &
 [ PRED pronoun_q_rel,ARG0 x & #x2, RSTR #hnd] >,
  OUTPUT.HCONS < [ HARG #hnd, LARG #lbl ] >].


på-to-on :=  monotonic_mtr &
[ CONTEXT.RELS < [ PRED "_rygg_n_rel", ARG0 #x2] , [ PRED "_sti_n_rel",
	ARG0 #x1] >,
  INPUT.RELS < arg012-relation &  [LBL #h, PRED "_på_p_rel", LBL #h1, ARG0 #e1,
	 ARG2 #x2] >,
  OUTPUT.RELS <[LBL #h,  PRED _on_p_rel, LBL #h1, ARG0 #e1, ARG1 #x1, ARG2 #x2] > ].



 



ild := monotonic_mtr &
[ INPUT.RELS < noun-relation &[ PRED "_ild_n_rel",ARG0 #x1, LBL #h1 ] >,
  OUTPUT.RELS < [ LBL #h1, PRED "_fire_n_rel",ARG0 #x1 ],
	arg01-relation & [ PRED "_open_j_rel", ARG0 e, ARG1 #x1, LBL #h1]
 > ].


vær-met:= monotonic_omtr &
[ INPUT.RELS < noun-relation &[ PRED "_vær-met_n_rel" ,ARG0 #x1, LBL #h1 ],
	quant-relation & [ PRED "udef_q_rel", ARG0 #x1, LBL #h2,
	 RSTR #h3] >,
  INPUT.HCONS < [ HARG #h3, LARG #h1] >,
  OUTPUT.RELS < arg01-relation & [ PRED "_weather_n_rel" ,ARG0 #x1,
	 LBL#h1, ARG1 u ],
	quant-relation & [ PRED bare_div_q_rel, ARG0 #x1, LBL #h2, RSTR #h3]
 >,
  OUTPUT.HCONS <  [ HARG #h3, LARG #h1] > ].

forsiktighet:= monotonic_omtr &
[ INPUT.RELS < noun-relation &[ PRED "_forsiktighet_n_rel" ,ARG0 #x1,
 LBL #h1 ],
	quant-relation & [ PRED "udef_q_rel", ARG0 #x1, LBL #h2,
	 RSTR #h3] >,
  INPUT.HCONS < [ HARG #h3, LARG #h1] >,
  OUTPUT.RELS < arg01-relation & [ PRED "_caution_n_rel" ,ARG0 #x1,
	 LBL#h1, ARG1 u ],
	quant-relation & [ PRED bare_div_q_rel, ARG0 #x1, LBL #h2, RSTR #h3]
 >,
 OUTPUT.HCONS <  [ HARG #h3, LARG #h1] > ].


	

bruk-av-to-use-gerund := monotonic_mtr &
[ CONTEXT [ RELS < [ PRED "bare_div_q_rel",
                      ARG0 #x4, RSTR #h2 ] >,
            HCONS < qeq & [ HARG #h2, LARG #h3 ] > ],
  INPUT.RELS < [ PRED "_bruk_n_rel", LBL #h3,
                  ARG0 #x4, ARG1 #x5 ] >,
  OUTPUT.RELS < [ PRED gerund_rel, LBL #h3,
                   ARG0 #x4, ARG1 #h ],
                 [ PRED "_use_v_1_rel", LBL #h4,
                   ARG0 e_no_tense & [ PROG + ], 
                   ARG2 #x5], [ PRED prpstn_m_rel, LBL #h,MARG #hnd] >,
  OUTPUT.HCONS < qeq & [ HARG #hnd, LARG #h4] >  ].

udef_compound := quantifier_mtr &
[ CONTEXT.RELS < [ PRED "unspec_rel", ARG2 #x1 ] >,
  INPUT.RELS < [ PRED "udef_q_rel", ARG0 #x1 ] >,
  OUTPUT.RELS < [ PRED udef_q_rel ] > ].

gen-to-bare_div := preposition_mtr &
[ CONTEXT.RELS < [ PRED "named_rel", CARG "Byfjellene"] >,
  INPUT.RELS < [ PRED "_på_p_rel" ] >,
  OUTPUT.RELS < [ PRED _in_p_rel ] > ].

1970 := mrs_transfer_rule &
[CONTEXT.RELS < [ PRED "_siden_p_rel", ARG1 #e, ARG2 #x1] >,
  INPUT.RELS <  [LBL #h1, PRED "__n_1970-tallet_rel", ARG0 #x1] >,
  OUTPUT.RELS < named-relation & [ LBL #h1, PRED yofc_rel,
 ARG0 #x1, CARG "fourdigitersatz" ],
 arg012-relation & [ PRED _since_p_rel,ARG0 e,  ARG1 #e, ARG2 #x2],
	arg012-relation & [ LBL #lbl,PRED poss_rel,ARG0 i,
	 ARG1 #x1, ARG2 #x2],
quant-relation & [ PRED def_explicit_q_rel, ARG0 #x2, RSTR #h2],
arg0-relation &[ PRED generic_nopro_rel, ARG0 #x2] >,
OUTPUT.HCONS < [ HARG #h2, LARG #lbl ] > ].

siden-cont-del := monotonic_mtr &
[CONTEXT.RELS < [ PRED"_klatrer_n_rel" ] >, 
 INPUT.RELS < [ PRED "_siden_p_rel"] >,
 OUTPUT.RELS < > ].



bok-om+om_sel := monotonic_mtr &
[CONTEXT.RELS < [ LBL #h1, PRED"_bok-om_n_rel", ARG0 #x1 ],
	 [ PRED "_friluftsliv_n_rel", ARG0 #x3] >, 
 INPUT.RELS < [ PRED "_om_p_sel_rel", ARG0 #x] >,
 OUTPUT.RELS <[LBL #h1, PRED _on_p_rel, ARG0 #x,ARG1 #x1, ARG2 #x3 ] > ].

utvalg-i_sel := monotonic_mtr &
[CONTEXT.RELS < [ LBL #h1, PRED"_bok-om_n_rel", ARG0 #x1 ] >, 
 INPUT.RELS < [ PRED "_i_p_sel_rel", ARG0 #x] >,
 OUTPUT.RELS <[LBL #h1, PRED _of_p_sel_rel, ARG0 #x,ARG1 u, ARG2 #x1 ] > ].

god_r_rel_rep := monotonic_mtr &
[CONTEXT.RELS < [  PRED"_utvalg-i_n_rel", ARG0 #x1 ] >, 
 INPUT.RELS < [ LBL #h1, PRED "_god_r_rel", ARG0 #x] >,
 OUTPUT.RELS <[ LBL #h1, PRED " _good_j_rel", ARG0 #x, ARG1 #x1, ARG2 i ] > ].


på+forhånd :=  monotonic_mtr &
[ INPUT.RELS < [ PRED "_forhånd_n_rel", ARG0 #x ],
	 [ PRED "_på_p_rel", ARG1 #e, ARG2 #x ]  >,
  OUTPUT.RELS < basic-arg1-relation & [ PRED "in+advance_r_rel", ARG1 #e] >].

slippe_v_rel := monotonic_mtr &
[CONTEXT.RELS < [  PRED"prpstn_m_rel", MARG #h1 ],
	 	  [  PRED"_bære_v_rel", LBL #lbl ] >, 
 INPUT.RELS   < [ LBL #h2, PRED "_slippe_v_rel", ARG0 #e, ARG2 #h3],
		  [ LBL #h3, PRED "prpstn_m_rel", MARG #h4]  >,
 INPUT.HCONS < [ HARG #h4, LARG #lbl ], [ HARG #h1, LARG #h2]  >,
 OUTPUT.RELS < arg01-relation & [ LBL #h4,  PRED "_have_v_rel", ARG0 #e,
 ARG1 #mod ],
		basic-arg1-relation & [ LBL #h5, PRED neg_rel, ARG1 #neg] >,
 OUTPUT.HCONS < [ HARG #neg, LARG #h4 ],[ HARG #mod, LARG #lbl],[ HARG #h1,
 LARG #h5]  > ].  


contxt-sørover_p_rel := monotonic_mtr &
[CONTEXT.RELS < [ PRED "_gå_v_rel", ARG0 #e, ARG1 #x1  ] >,
 INPUT.RELS <  [ LBL #h, PRED "_sørover_p_rel", ARG1 #e, ARG2 #x2] >,
 OUTPUT.RELS < [ PRED "_south_j_rel", ARG1 #x1, ARG2 i] ,
		arg012-relation & [ LBL #h, PRED _along_p_rel, ARG2 #x2, 
	ARG1 #e ] > ] .

lørdagsåpen-to-on-saturdays := monotonic_mtr &
[ CONTEXT.RELS < [ CARG "Turlaget", ARG0 #x3] >,
  INPUT.RELS < [ LBL #h, PRED "_lørdagsåpen_r_rel", ARG1 #e],
  [ LBL #h, PRED "_på_p_rel", ARG2 #x3] >,
   OUTPUT.RELS < [ LBL #h, PRED "_open_j_rel",ARG0 e, ARG1 #x3 ],
  [LBL #h, PRED _on_p_temp_rel, ARG0 e, ARG1 #x3 , ARG2 #x2],
  quant-relation & [ PRED bare_div_q_rel, ARG0 #x2, RSTR #h1],
   named-relation & [ LBL #lbl, PRED dofw_rel, ARG0 #x2,CARG "sat"] >,
   OUTPUT.HCONS < [ HARG #h1, LARG #lbl ] > ].