;;; Hey, emacs(1), this is -*- Mode: TDL; Package: LKB; -*- got it?

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;;; first transfer phase, NorGram-specific accomodation: these rules primarly
;;; patch up `deficiencies' in NorGram MRSs, e.g. ditch selected relations.
;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;;; a couple of predicates for which we know no way of mapping into ERG terms,
;;; or cannot be bothered right now.
;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;
;;; _fix_me_
;;; these must not use handle-valued ARG1 and ARG2, if we want the structure to
;;; scope; NorGram currently makes that impossible.            (15-feb-04; oe)
;;;

subjectivized := erase_mtr &
[ INPUT.RELS < [ PRED "subjectivized_rel" ] > ].

topic := erase_mtr &
[ INPUT.RELS < [ PRED "topic_rel" ] > ].





;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;;; selected-for prepositions: the theory is that they do not contribute to the
;;; semantics, since they have also been incorporated into their main predicate
;;; (e.g. in `_bruk-av_n' et al.); however, maybe revisit one day for cases 
;;; like `interesse { for | i }'.   (joint taxi ride with helge: 4-mar-04; oe)
;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

av_sel := erase_mtr &
[ INPUT.RELS < [ PRED "_av_p_sel_rel" ] > ].

med_sel := erase_mtr &
[ INPUT.RELS < [ PRED "_med_p_sel_rel" ] > ].

free-relative-der := erase_mtr &
[ INPUT.RELS < [ PRED "_der_rel" ] > ].


contxt-etter-to-of_p_rel := monotonic_mtr & 
[ INPUT.RELS < [ LBL #h, PRED "_etter_p_sel_rel", ARG0 e , ARG2 #x ] >,
  OUTPUT.RELS < [ LBL #h, PRED _of_p_sel_rel , ARG0 e, ARG1 u, ARG2 #x ] > ].  


;;; NorGram considers imperatives untensed, unlike the ERG (even though dan
;;; feels he should probably call then `non-past' rather); this would appear
;;; to call for a rule like the following:
;;;
;;; --- as of 19-feb, `pres' is now the NorGram default for imperatives too.
;;;

imp_m_present := monotonic_mtr &
[ CONTEXT [ RELS < [ PRED "imp_m_rel", MARG #h1 ] >,
            HCONS < qeq & [ HARG #h1, LARG #h2 ] > ],
  INPUT.RELS < [ LBL #h2, ARG0 [ TENSE notense ] ] >,
  OUTPUT.RELS < +copy+ & [ ARG0 [ TENSE pres ] ] > ].