;;; Hey, emacs(1), this is -*- Mode: TDL; Coding: utf-8; -*- got it?

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;;; first transfer phase, GG-specific accomodation: these rules primarly patch
;;; up `deficiencies' in GG MRSs, e.g. ditch selected relations.
;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;;; selected-for prepositions: the theory is that they do not contribute to the
;;; semantics, since they have also been incorporated into their main predicate
;;; (e.g. in `_bruk-av_n' et al.); however, maybe revisit one day for cases 
;;; like `interesse { for | i }'.   (joint taxi ride with helge: 4-mar-04; oe)
;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

p_sel_ditch_gf := elision_mtr &
[ INPUT.RELS < [ PRED "~_p_sel_rel$" ] > ].


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;;; as a general precaution, make sure all referential indices are bound by a
;;; quantifier; this is robustness to a degree of taking chances, i guess
;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

missing_quantifier_sg_count_gf := monotonic_mtr &
[ CONTEXT.RELS < [ PRED "~_n_rel$", LBL #h1,
                   ARG0 #x2 & x & [ NUM sg, DIV - ] ] >,
  FILTER.RELS < [ ARG0 #x2, RSTR #h3 & h ] >,
  OUTPUT [ RELS < [ PRED "some_q_indiv_rel", ARG0 #x2, RSTR #h4 ] >,
           HCONS < qeq & [ HARG #h4, LARG #h1 ] > ],
  FLAGS.EQUAL < #x2, #h3 > ].

missing_quantifier_sg_count_gf := monotonic_mtr &
[ CONTEXT.RELS < [ PRED "~_n_rel$", LBL #h1,
                   ARG0 #x2 & x & [ NUM sg ] ] >,
  FILTER.RELS < [ ARG0 #x2, RSTR #h3 & h ] >,
  OUTPUT [ RELS < [ PRED "some_q_rel", ARG0 #x2, RSTR #h4 ] >,
           HCONS < qeq & [ HARG #h4, LARG #h1 ] > ],
  FLAGS.EQUAL < #x2, #h3 > ].

missing_quantifier_pl_gf := monotonic_mtr &
[ CONTEXT.RELS < [ PRED "~_n_rel$", LBL #h1, ARG0 #x2 & x & [ NUM pl ] ] >,
  FILTER.RELS < [ ARG0 #x2, RSTR #h3 & h ] >,
  OUTPUT [ RELS < [ PRED "bare_div_q_rel", ARG0 #x2, RSTR #h4 ] >,
           HCONS < qeq & [ HARG #h4, LARG #h1 ] > ],
  FLAGS.EQUAL < #x2, #h3 > ].