;;; Hey, emacs(1), this is -*- Mode: TDL; Coding: utf-8; -*- got it?

;;;
;;; PH 2007-10-04: 
;;;
;;; @ Han dømmer om det. >> He is the judge of that.
;;;
arg12prep_be_n_pp_mtr := monotonic_mtr &
[ INPUT.RELS < [ LBL #h1, ARG0 #e1, ARG1 #x1, ARG2 #x2 ] >,
  OUTPUT [ RELS < [ LBL #h2, ARG0 #x3, ARG1 #x2 ],
		  [ PRED _the_q_rel, ARG0 #x3 & [ NUM sg, PERS 3, GRIND - ], 
		    RSTR #h3 ],
		  [ PRED _be_v_id_rel, LBL #h1, ARG0 #e1, ARG1 #x1, ARG2 #x3 ],
		  [ PRED num_equate, ARG0 #x3, ARG1 #x1 ]>,
	   HCONS < qeq & [ HARG #h3, LARG #h2 ] > ] ].
;;;
;;; PH 2007-10-01
;;;
;;; @ Han drakk seg full. >> He got drunk.
;;;
arg1+a_arg1+vp_v_mtr := monotonic_mtr &
[ INPUT.RELS < [ LBL #h0, ARG0 #e0, ARG1 #x0, ARG2 #h6 ],
	       [ LBL #h6, ARG1 #x0 ] >,
  OUTPUT [ RELS < [ LBL #h3, ARG0 e, ARG1 #x0 ],
		  [ PRED "_get_v_state_rel", 
		    LBL #h0, ARG0 #e0, ARG1 #x0, ARG2 #h1 ] >,
          HCONS < qeq & [ HARG #h1, LARG #h3 ] > ] ].

arg1+a_arg1+vp_v_omtr := arg1+a_arg1+vp_v_mtr & optional_mtr.

;;;
;;; @ Han satte fast isen. >> He got the ice caught.
;;;                                                             (16-jan-08; ph)
arg12_arg123+vp_v_mtr := monotonic_mtr &
[ INPUT.RELS < [ LBL #h0, ARG0 #e0, ARG1 #x0, ARG2 #x1 ] >,
  OUTPUT [ RELS < [ LBL #h3, ARG0 #e1, ARG2 #x1 ],
		  [ PRED "_get_v_state_rel", 
		    LBL #h0, ARG0 #e0, ARG1 #x0, ARG2 #x1, ARG3 #h1 ],
		  [ PRED parg_d_rel, LBL #h3, ARG1 #e1, ARG2 #x1 ]>,
          HCONS < qeq & [ HARG #h1, LARG #h3 ] > ] ].

arg12_arg123+vp_v_omtr := arg12_arg123+vp_v_mtr & optional_mtr.

;;;
;;; @ Abrams rotet seg borti isen. >> Abrams got mixed up in the ice.
;;;                                                             (15-jan-08; ph)
arg12_arg12+vp-pp_v_mtr := monotonic_mtr &
[ INPUT.RELS < [ LBL #h0, ARG0 #e0, ARG1 #x0, ARG2 #x1 ] >,
  OUTPUT [ RELS < [ LBL #h3, ARG0 #e1, ARG2 #x0 ],
		  [ LBL #h3, ARG0 e_untensed, ARG1 #e1, ARG2 #x1 ],
		  [ PRED "_get_v_state_rel", 
		    LBL #h0, ARG0 #e0, ARG1 #x0, ARG2 #h1 ],
		  [ PRED parg_d_rel, LBL #h3, ARG1 #e1, ARG2 #x0 ] >,
          HCONS < qeq & [ HARG #h1, LARG #h3 ] > ] ].

arg12_arg12+vp-pp_v_omtr := arg12_arg12+vp-pp_v_mtr & optional_mtr.

;;;
;;; @ Han finner fram. >> He found his way.
;;;
arg1_arg12_poss_mtr := monotonic_mtr &
[ INPUT.RELS  < [ LBL #h1, 
		  ARG0 #e1, ARG1 #x1 ] >,
  OUTPUT [ RELS < [ LBL #h1, 
		    ARG0 #e1, ARG1 #x1 & [ NUM #num, GEND #gend ], ARG2 #x2 ],
		  [ LBL #h2, ARG0 #x2 & [ PERS 3, NUM sg, GRIND - ] ],
		  [ PRED poss_rel, LBL #h2,
                    ARG0 e_untensed, ARG1 #x2, ARG2 #x3 ],
		  [ PRED pronoun_q_rel,
		    ARG0 #x3 & [ NUM #num, GEND #gend ], RSTR #h3 ],
		  [ PRED pron_rel,
		    LBL #h4, ARG0 #x3 ],
		  [ PRED def_explicit_q_rel,
		    ARG0 #x2, RSTR #h5 ],
		  [ PRED num_equate, ARG0 #x3, ARG1 #x1 ] >,
	   HCONS < qeq & [ HARG #h3, LARG #h4 ], 
		   qeq & [ HARG #h5, LARG #h2 ] > ] ].

arg1_arg12_poss_omtr := arg1_arg12_poss_mtr & optional_mtr.

;;;
;;; @ Abrams eter seg mett. >> Abrams eats his fill.
;;;
arg1+a_arg12_poss_mtr := monotonic_mtr &
[ INPUT.RELS  < [ LBL #h1, 
		  ARG0 #e1, ARG1 #x1, ARG2 #h6 ],
		[ LBL #h6, ARG1 #x1 ] >,
  OUTPUT [ RELS < [ LBL #h1, 
		    ARG0 #e1, ARG1 #x1 & [ NUM #num, GEND #gend ], ARG2 #x2 ],
		  [ LBL #h2, ARG0 #x2 & [ PERS 3, NUM sg, GRIND - ] ],
		  [ PRED poss_rel, LBL #h2,
                    ARG0 e_untensed, ARG1 #x2, ARG2 #x3 ],
		  [ PRED pronoun_q_rel,
		    ARG0 #x3 & [ NUM #num, GEND #gend ], RSTR #h3 ],
		  [ PRED pron_rel,
		    LBL #h4, ARG0 #x3 ],
		  [ PRED def_explicit_q_rel,
		    ARG0 #x2, RSTR #h5 ] >,
	   HCONS < qeq & [ HARG #h3, LARG #h4 ], 
		   qeq & [ HARG #h5, LARG #h2 ] > ] ].

arg1+a_arg12_poss_omtr := arg1+a_arg12_poss_mtr & optional_mtr.

;;;
;;; @ Abrams kastet av seg klærne. >> Abrams tore off his clothes.
;;;                                                              (9-jan-08; ph)
arg12_arg12_poss_mtr := monotonic_mtr &
[ CONTEXT [ RELS < [ LBL #h2,
		     ARG0 #x2 ] >,
	    HCONS < qeq & [ HARG #h5, LARG #h2 ] > ],
  INPUT.RELS  < [ LBL #h1, 
		  ARG0 #e1, ARG1 #x1, ARG2 #x2 ],
		[ ARG0 #x2, RSTR #h5 ] >,
  OUTPUT [ RELS < [ LBL #h1, 
		    ARG0 #e1, ARG1 #x1 & [ NUM #num, GEND #gend ], ARG2 #x2 ],
		  [ PRED def_explicit_q_rel,
		    ARG0 #x2, RSTR #h5 ],
		  [ PRED poss_rel, LBL #h2,
                    ARG0 e_untensed, ARG1 #x2, ARG2 #x3 ],
		  [ PRED pronoun_q_rel,
		    ARG0 #x3 & [ NUM #num, GEND #gend ], RSTR #h3 ],
		  [ PRED pron_rel,
		    LBL #h4, ARG0 #x3 ] >,
	   HCONS < qeq & [ HARG #h3, LARG #h4 ] > ] ].

arg12_arg12_poss_omtr := arg12_arg12_poss_mtr & optional_mtr.

;;;
;;; @ den heimste gården >> the farm closest to home
;;;
adjective_superl+pp_mtr := monotonic_mtr &
[ INPUT.RELS < [ LBL #h0, ARG0 #e0, arg1 #x0 ] >,
  OUTPUT [ RELS <  [ LBL #h0, ARG0 #e0, arg1 #x0 ],
		   [ LBL #h0, PRED _to_p_rel, 
		     ARG0 e_untensed, ARG1 #e0, ARG2 #x1 ],
		   [ PRED def_implicit_q_rel, ARG0 #x1, RSTR #h1 ],
		   [ LBL #h2, PRED place_n_rel, ARG0 #x1 ],
		   [ LBL #h2, PRED _home_p_rel, ARG0 e_untensed, ARG1 #x1 ] >,
	   HCONS < qeq & [ HARG #h1, LARG #h2 ] > ] ].